######################################################################
# insert here aliases...

echo sourcing ".aliases"
alias a alias


alias t2  '(xterm -sf  -T "T2" -name "T2" -geometry 80x40+60+100 -bw 3 -bd yellow -sb -sl 5000 -bg grey15 -fg yellow -ms green -cr red -e rlogin t2 &)' # >>&/dev/null

#########  aliases that depend on $HOSTTYPE

# Always have the "delete" command
if (! $?HOSTTYPE) then
  alias delete '\rm -f'
else
  if ($HOSTTYPE != rs6000) alias delete '\rm -f'
endif


#########  aliases that depend on $shell

# Always source file .cdrc, if readable
if ($shell:t == tcsh) then
  alias srccdrc sleep 0		#Since tcsh does it by default - do nothing
else
  alias srccdrc 'if (-r .cdrc) source .cdrc'
endif

# Prompt modifications
alias ok 'set prompt="%m %~ [%h] " ; set prompt_flag = "ok"'
alias ko 'set prompt="%m $cwd:t [\\!] " ; set prompt_flag = "ko"'
alias sko 'if ($?prompt_flag && $prompt_flag == "ko") set prompt="%m $cwd:t [\\!] " '
#It did not work for
#alias sko 'if ($?prompt_flag && $prompt_flag == "ko") ko '

#Changing directories, using the above
alias cd 'set old=$cwd;chdir \!* ; srccdrc; setenv PWD $cwd ; sko'
alias b 'set back=$old; set old=$cwd; cd $back; unset back;setenv PWD $cwd'
alias up 'cd ..'

########### For activating 'diff', I usually prefer 'less' - if it exists
#
alias dif1	'\diff -btC 1 \!* | more'

set found = `which less`	# Do we have 'less' ?
if ( $#found > 1 ) then		# 'less' not found
  alias dif	'\diff -btC \!* | more'
else
  alias dif	'\diff -btC \!* | less'
endif
unset found

##  RCS "diff"
alias rdif0	'rcsdiff -btc0'
alias rdif	rcsdiff



###############  The rest of aliases

alias gcc  gcc -ansi -pedantic -Wall
alias GCC  gcc -ansi -pedantic -Wall -Wtraditional -Wconversion \
	-Wshadow -Wid-clash-31 -Wpointer-arith -Wcast-qual -Wcast-align \
	-Wwrite-strings -Wstrict-prototypes -fno-common 

alias h 'history -r | more'
alias so source
alias md mkdir
alias rd rmdir
alias rm  rm -i
alias cp cp -i
alias mv mv -i
alias m more

if ($shell:t == tcsh) then
  alias ls ls-F
else
  alias ls ls -F
endif
alias lsa ls -a
alias lsl 'ls -l'
alias lsla 'ls -al'
alias lsr 'ls -rtl'
alias lsra 'ls -artl'
alias lst 'ls -lt'
alias lsf  '\ls -Fl \!*| grep ^-'
alias lsdl '\ls -Fl \!*| grep ^d' 
alias lsd  '\ls -F \!*| grep /$' 
alias lsul '\ls -F \!*| grep -v @'
alias lslk '\ls -F \!*| grep  @'
alias lslkl '\ls -Fl \!*| grep -e "->"'
alias lsR 'ls -alR \!*'

alias j 'jobs -l'
alias g grep
alias gi grep -i
alias gn grep -n
alias gin grep -in
alias gv grep -v

alias sl ln -s
alias tf 'tail -f'
alias ? whoami
alias whof '\who | sort'
alias wis 'whereis -b -B `echo $path` -f'

alias w_d	'echo DISPLAY = $DISPLAY'
alias s_d	'setenv DISPLAY \!:1\:0.0 '
alias s_d_h	'setenv DISPLAY `hostname`:0.0'
alias w_p	'echo PRINTER = $PRINTER'
alias s_p	'setenv PRINTER'

alias tar       '\tar  -cvf'    # <tar name> <dir name>
alias untar     '\tar  -xvf'    # <tar name>